---

Hallo,

ich würde gerne wissen, ob ich per Makro die Ansicht senkrecht auf ein Element einstellen kann...und wenn es geht, würde mir ein codebeispiel sehr weiter helfen...

Vielen Dank

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo Marc,

woher bekommst du das Element? Ist das ein Script-Input oder soll der Anwender eine Plane selektieren? Ein paar mehr Info´s wären hilfreich 

An den Befehl "normal View" kommst du nur über einen CATIA.StartCommand. Hier kannst du aber keine Input-Elemente angeben. D.h. ev. wäre es sinnvoller die "named Views" zu verwenden

------------------
MFG Daniel

Die KATJA ist halt doch nur ne zickige Französin

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo,

ich habe eine fixe Ebene im Modell und nach einer reihe von Geometrieerzeugung will ich zum schluss, wenn alles fertig ist mit senkrechtem Blick auf die Ebene von dem gesamten Modell (alles reingezoomt) ein Screenshot machen....

Die Ebene liegt irgendwo im Raum...

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Servus
Dazu könntest du dir eine Camera (unter definierte Ansichten -> hinzufügen) erstellen und dann auf "alles einpassen" klicken.
IMHO sollte das sich auch mit einem Makro erschlagen lassen. Es gab mel ein paar Beiträge zur Erstellung von Screenshots mit einem Makro

Gruß
Bernd

------------------
Warum einfach, wenn es auch kompliziert geht.

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo Marc,

also um das von Bernd mal zu verdeutlichen hier ein kleines Script, das dir dein Bauteil auf die "Top View" ausrichtet und anschließend einen Reframe macht.

Code:

---

Sub CATMain()

    Dim oDoc As Document
    Dim oCams As Cameras
    Dim oCam As Camera3D
    Dim oViewPoint As Viewpoint3D
    Dim oSpecWindow As SpecsAndGeomWindow
    Dim oViewer As Viewer3D
   
    Set oDoc = CATIA.ActiveDocument
    Set oCams = oDoc.Cameras
    Set oCam = oCams.Item(6)
    Set oViewPoint = oCam.Viewpoint3D
    Set oSpecWindow = CATIA.ActiveWindow
    Set oViewer = oSpecWindow.ActiveViewer
    oViewer.Viewpoint3D = oViewPoint
    oViewer.Reframe

End Sub

---

------------------
MFG Daniel

Die KATJA ist halt doch nur ne zickige Französin

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo,

vielen dank, aber das Problem ist, das ich keine fixe Camera ansprechen will, da meine ebene irgendwo im Raum liegt und ich nur senkrecht draufschauen will (auf die Ebene).

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo,

soweit ich weiß kann man diesen Befehl aber nur mit einem StartCommand ansprechen. Dies ist aber ein asynchrone Operation (sprich dein Script wartet nicht auf Beendigung des Befehl´s sondern läuft einfach weiter). Dies kann zu Laufzeitfehlern führen. Des weiteren hast du keine Inputs, sprich du musst die Ebene wie beim "normalen" Ausführen des Befehls durch den Anwender selektieren lassen und kannst sie nicht durch eine Selektion innerhalb des Scriptes an den Befehel weitergeben 

------------------
MFG Daniel

Die KATJA ist halt doch nur ne zickige Französin

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

ich weiß....

sehr schade :-( muss ich wohl eine nameview erstellen und dann senkrecht draufschauen

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo MarcDe,

das müsste gehen, du brauchst aber wahrscheinlich noch eine Richtung.
Man kann die Richtung einer Ebene (die zwei Richtungsvektoren) über GetFirstAxis und GetSecondAxis oder SPAWorkbench fragen.
Eine Viewpoint3D hat zwei Richtungen: SightDirection und UpDirection. Den ersten bekommst du als Kreuzprodut der zwei Richtungen der Ebene. Für den zweiten kannst du einer der Richtungsvektoren verwenden, wobei da was exakteres sicherlich günstiger wäre.
Mit PutSigthDirection, bzw. PutUpDirection kannst du dann die entsprechende Richtungen der aktuellen Ansicht setzen. (oViewPoint.PutSightDirection HierDieRichtungDerEbene)

Gruß,
Zoltan

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hi Zoltan, ich sitze aktuell an dem gleichen Thema. Hast du hierzu einen Beispiel Code, wie du über die Achsen der Ebene den ViewPoint3D definierst? Danke vorab.

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Servus

Anbei ein Beispiel:

Code:

---

Sub CATMain()

    Dim oPartDoc as PartDocument
    Dim oSel as Selection
    Dim oPlanarFace as Plane
    Dim aVector1(2)
    Dim aVector2(2)
    Dim aVectorNormal(2)
    Dim aVectorOrigin(2)
    Dim sUserSel as String
    Dim oWindow As Window
    Dim oViewer3D As Viewer
    Dim oViewpoint3D As Viewpoint3D

    Set oPartDoc = Catia.ActiveDocument
    Set oSel = oPartDoc.Selection
   
    'Ebene selektieren
    ReDim aFilter(0)     
    aFilter(0) = "Plane"

    sUserSel = oSel.SelectElement2(aFilter, "Select a plane", True)
        
    If sUserSel <> "Normal" Then Exit Sub

    'Werte auslesen
    Set oPlanarFace = oSel.Item(1).Value
    oPlanarFace.GetFirstAxis aVector1
    oPlanarFace.GetSecondAxis aVector2
    oPlanarFace.GetOrigin aVectorOrigin
   
    'Normale über Kreuzprodukt
    aVectorNormal(0) = aVector1(1) * aVector2(2) - aVector1(2) * aVector2(1)
    aVectorNormal(1) = aVector1(2) * aVector2(0) - aVector1(0) * aVector2(2)
    aVectorNormal(2) = aVector1(0) * aVector2(1) - aVector1(1) * aVector2(0)

    'Ansicht ausrichten
    Set oWindow = CATIA.ActiveWindow
    Set oViewer3D = oWindow.ActiveViewer
    Set oViewpoint3D = oViewer3D.Viewpoint3D
   
    oViewpoint3D.PutOrigin          aVectorOrigin  'oder auf den Ursprung array(0,0,0)
    oViewpoint3D.PutSightDirection  aVectorNormal
    oViewpoint3D.PutUpDirection     aVector2 'oder zB array(0,0,1) mit Z nach oben
   
    oViewer3D.Reframe

End Sub

---

Gruß
Bernd

------------------
Warum einfach, wenn es auch kompliziert geht.

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP