---

Guten Morgen, ich habe div. Blechbauteile (IPT)! diese IPT‘s mit Stanzbilder hätte ich gerne automatisch bemaßt. Ist Es möglich, dass auch schon in der IPT über eine Regel zu erstellen, oder muss ich eine DWG anlegen, und dort eine Regel schreiben?

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Moin

Du kannst auch bereits in der IPT Skizzenbemaßungen oder 3D-Modellanmerkungen an das Stanzbild setzen. Das kommt darauf an, wie die zu bemaßende Geometrie erzeugt wird. Wenn eine Reihe Löcher erst durch eine Reihenanordnung erzeugt wird, kann man in der Skizze logischerweise den Lochabstand noch nicht bemaßen. Eine Mischung aus beiden ist auch möglich.
Die Bemaßungen können in der Ansicht auf der Zeichnung abgerufen und eingeblendet werden. Meist fliegen die Bemaßungen dann irgendwo hin und das Positionieren per Code ist nicht ganz einfach.
Generell, wenn die zu bemaßenden Objekte nicht bereits irgendwie gekennzeichnet sind, ist es per Code wirklich eine Herausforderung eine funktionale und sinnvolle Bemaßung zu erstellen. Einfach die Länge oder den Radius jeder Kante zu bemaßen ist meist unzureichend.

------------------
MfG
Ralf

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Die Stanzbilder werden mit einer Regel platziert, ich bräuchte auch nur die Mittelpunkt Bemaßung!

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Und diese 3D Anmerkungen in IPT-INVENTOR funktioniert auch mit ilogic?

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Moin

Die Stanzbildermittelpunkte bekommt man im Modell über die PunchToolFeature.CenterPoints als Skizzenpunktkollektion. Für die 3D-Anmerkungen wirst du die mit einem SketchToModelTransform in den Modellraum übertragen müssen. Dann musst du dir noch überlegen, was du als Nullpunkt nimmst. Koordinatenursprung wäre hier das einfachste. Vom Ursprung und dem Skizzenpunkt jeweils ein GeometryIntent erstellen, die Blechfläche als AnnotationPlane definieren und dann noch einen Punkt für die TextPosition ermitteln. Dann hast du alle Infos zusammen, glaub ich.

Seit Version 2018 sollte es funktionieren bzw. alles was die API bietet ist auch über iLogic erreichbar.

------------------
MfG
Ralf

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Vielen Dank für diesen Info, wie würde das Code-technisch aussehen? Oder besser gefragt kannst du mich dabei unterstützen?

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Screenshot_Modellbemassung.jpg

Moin

Anbei ein stark vereinfachtes Beispiel. Erzeuge ein Blechteil mit einer Fläche auf der XY-Ebene und die linke untere Ecke sollte im Ursprung liegen. Dann einfach ein paar Stanzungen einfügen und mal laufen lassen. Die Positionierung der Maße ist durcheinander weil einfach die Punkte wie sie kommen benutzt werden. Da müßte man die Kollektionen erst aufsteigend nach X bzw. Y sortieren und auch der Abstand zum Modell sollte einer sinnvollen Regel folgen.
Mit der CreateAnnotationPlaneDefinitionUsingPlane Methode müßte es auch gehen die Plane der Skizze des Stanzfeatures zu nehmen. Immer davon auszugehen, das die Fläche auf XY liegt dürfte nicht funktionieren. Ebenso sollte die X-Achsenrichtung nicht fix über die Ursprungs X-Achse definiert werden. Da ist noch viel Arbeit übrig. 

Code:

---

Option Explicit on

Dim oApp As Inventor.Application = ThisApplication
Dim oDoc As PartDocument = oApp.ActiveDocument
Dim oCompDef As SheetMetalComponentDefinition= oDoc.ComponentDefinition

If oCompDef.Features.PunchToolFeatures.Count = 0 Then
    Call MsgBox("No punches.", vbInformation)
    Exit Sub
End If
   
' Create an AnnotationPlaneDef
' Definition is reused for each annotation
Dim oAnnoPlaneDef As AnnotationPlaneDefinition = oCompDef.ModelAnnotations.CreateAnnotationPlaneDefinitionUsingPlane(oCompDef.WorkPlanes.Item(3), oCompDef.WorkAxes.Item(1)) 'XY-Ebene, X-Achse

' Get the Origin
Dim oOrigin As WorkPoint= oCompDef.WorkPoints.Item(1)

' Create a GeometryIntent of the origin
Dim oIntent1 As GeometryIntent = oCompDef.CreateGeometryIntent(oOrigin)

' Set a reference to the LinearModelDimensions
Dim oLinModelDims As LinearModelDimensions = oCompDef.ModelAnnotations.ModelDimensions.LinearModelDimensions

' Traverse the PunchToolFeatures
Dim oFeat As PunchToolFeature
For Each oFeat In oCompDef.Features.PunchToolFeatures
    ' get the CenterPoints collection
    Dim oColl As ObjectCollection = oFeat.PunchCenterPoints
   
    Dim oPoint As SketchPoint
    For Each oPoint In oColl
        Dim oIntent2 As GeometryIntent = oCompDef.CreateGeometryIntent(oPoint)
        Dim oSketch As PlanarSketch= oPoint.Parent
        Dim oModelPoint As Point = oSketch.SketchToModelSpace(oPoint.Geometry)
        Dim oTextPos As Point
        Dim oLinModelDimDef As LinearModelDimensionDefinition
        Dim oLinModelDim As LinearModelDimension
       
        ' horizontal
        oTextPos = oApp.TransientGeometry.CreatePoint(oModelPoint.X / 2, -oModelPoint.Y, 0)
        oLinModelDimDef = oLinModelDims.CreateDefinition(oIntent1, oIntent2, oAnnoPlaneDef, oTextPos, kHorizontalDimensionType)
        oLinModelDim = oLinModelDims.Add(oLinModelDimDef)
       
        ' vertical
        oTextPos = oApp.TransientGeometry.CreatePoint(-oModelPoint.X, oModelPoint.Y / 2, 0)
        oLinModelDimDef = oLinModelDims.CreateDefinition(oIntent1, oIntent2, oAnnoPlaneDef, oTextPos, kVerticalDimensionType)
        oLinModelDim = oLinModelDims.Add(oLinModelDimDef)
    Next
Next

---

------------------
MfG
Ralf

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Guten Morgen, herzlich Dank....

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

22-11-2024_10-06-02.jpg

Guten Morgen, funktioniert das auch bei ifeature?

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP