---

Screenshot2025-03-25091712.png

Hallo,
in meinem Automatisierungsprojekt kommen immer wieder neue Funktionen dazu, wo ich leider mit meinen bescheidenen Programmierkenntnissen anstehe.
Ich würde gerne per ilogic oder VBA das Kantensymbol mit der Option oberer und unterer Wertebereich -0.2 / -0.3 und die Klammer (Bedingung für alle Kanten mit mehr als einer Ausnahme) automatisch an einem definierten Punkt auf der Zeichnung platzieren.
Wäre cool, wenn mir jemand helfen könnte. Mit dem nachfolgenden Beispiel aus der API komme ich leider nicht weiter.

Public Sub CreateEdgeSymbol()
   
    ' Set a reference to the drawing document.
    ' This assumes a drawing document is active.
    Dim oDrawDoc As DrawingDocument
    Set oDrawDoc = ThisApplication.ActiveDocument

    ' Set a reference to the active sheet.
    Dim oActiveSheet As Sheet
    Set oActiveSheet = oDrawDoc.ActiveSheet

    ' Set a reference to the TransientGeometry object.
    Dim oTG As TransientGeometry
    Set oTG = ThisApplication.TransientGeometry
   
    ' Specify the leader points
    Dim oPoints(1 To 2) As Point2d
    Set oPoints(1) = oTG.CreatePoint2d(10, 10)
    Set oPoints(2) = oTG.CreatePoint2d(13, 15)
     
    Dim oLeaderPoints As ObjectCollection
    Set oLeaderPoints = ThisApplication.TransientObjects.CreateObjectCollection
   
    Dim i As Long
    For i = 1 To 2
        Call oLeaderPoints.Add(oPoints(i))
    Next
   
    Dim oEdgeSymbolDef As EdgeSymbolDefinition
    Set oEdgeSymbolDef = oActiveSheet.EdgeSymbols.CreateDefinition(kEdgeSymbolValueNoValues, kAllEdgesIndicationType)
   
    ' Create teh edge symbol.
    Dim oEdgeSymbol As EdgeSymbol
    Set oEdgeSymbol = oActiveSheet.EdgeSymbols.Add(oLeaderPoints, oEdgeSymbolDef)
End Sub

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo Jürgen
für Inventor VBA Themen gibt es ein Inventor VBA Brett:

https://ww3.cad.de/cgi-bin/ubb/forumdisplay.cgi?action=topics&forum=Inventor+VBA&number=258&DaysPrune=1000&LastLogin=&mystyle=

wenn du dort bitte dein Anliegen posten würdest?

------------------
lg   
Tom

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Moin

Ich hab ihn mal herüber geholt.

Code:

---

Public Sub CreateEdgeSymbol()
 
    ' Set a reference to the drawing document.
    ' This assumes a drawing document is active.
    Dim oDrawDoc As DrawingDocument
    Set oDrawDoc = ThisApplication.ActiveDocument

    ' Set a reference to the active sheet.
    Dim oActiveSheet As Sheet
    Set oActiveSheet = oDrawDoc.ActiveSheet

    ' Set a reference to the TransientGeometry object.
    Dim oTG As TransientGeometry
    Set oTG = ThisApplication.TransientGeometry
 
    Dim oLeaderPoints As ObjectCollection
    Set oLeaderPoints = ThisApplication.TransientObjects.CreateObjectCollection
 
    Call oLeaderPoints.Add(oTG.CreatePoint2d(10, 10))
   
    Dim oEdgeSymbolDef As EdgeSymbolDefinition
    Set oEdgeSymbolDef = oActiveSheet.EdgeSymbols.CreateDefinition(kEdgeSymbolValueDirectionUndefined, kMajoritySymbolWithMoreExceptionIndicationType)
   
    oEdgeSymbolDef.RangeOfValues = True
    oEdgeSymbolDef.VerticalValue = "-0,2"
    oEdgeSymbolDef.VerticalValueLower = "-0,3"
    oEdgeSymbolDef.UndefinedValue = "-0,2"
    oEdgeSymbolDef.UndefinedValueLower = "-0,3"
 
    ' Create teh edge symbol.
    Dim oEdgeSymbol As EdgeSymbol
    Set oEdgeSymbol = oActiveSheet.EdgeSymbols.Add(oLeaderPoints, oEdgeSymbolDef)
End Sub

---

------------------
MfG
Ralf

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hi Ralf
Super, genau was ich gesucht habe!

Herzlichen Dank!

Gruss
Jürg

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP