---

Hallo,

ist es irgendwie moeglich die Position einer Tabelle (zBsp. Revisionstabelle) auf einer Zeichnung nicht auf die linke untere Ecke des Blattes sonder auf die rechte untere Ecke beziehen zu lassen.
Hintergrund: ich will das die Revisionstabelle immer an der gleichen Stelle bezogen auf das Schriftfeld erscheint.

------------------
Barbarus hic ego sum, quia non intellegor ulli!

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Schieb sie dorthin wo sie gebraucht wird. Sie rastet an Linien oder Punkten der Schriftfelddefinition ein.

------------------
Grüße von Harry

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Zitat:

---

Original erstellt von Harry G.:
Schieb sie dorthin wo sie gebraucht wird. Sie rastet an Linien oder Punkten der Schriftfelddefinition ein.

---

das weis ich, aber das Problem ist das beim Aendern der Blattgroesse die Position wieder neu festgelegt werden muss. Es waehre doch besser wenn man dieses nicht durchfuehren muesste, einfach nur um es ein bisschenn einfacher zun haben.

------------------
Barbarus hic ego sum, quia non intellegor ulli!

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo

Dazu müßte man an die Skizze heran kommen, auf der die Revisionstabelle basiert. Dort könnte man dann den Verbindungspunkt von links oben auf rechts unten ändern und würde das von dir gewünschte Verhalten erreichen. Man könnte dann die Revisionstabelle auch schön zerlegen, wenn man etwas zu sehr verdreht. Leider traut Autodesk dem User solche Eingriffe nicht zu. 

------------------
MfG
Ralf

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Zitat:

---

Original erstellt von rkauskh:
... Dazu müßte man an die Skizze heran kommen, auf der die Revisionstabelle basiert. Dort könnte man dann den Verbindungspunkt von links oben auf rechts unten ändern ...

---

Dazu müsste es erst einmal eine Skizze geben. Die Revisionstabelle ist genauso wie z.B. die Teileliste ein dynamisches Tabellenobjekt, das auf keinerlei Skizze basiert.

Und einen Verbindungspunkt gibt es bei Tabellenobjekten auch oben links nicht.

Dennoch wäre es schön, könnte man Tabellenobjekte irgendwie an Rahmen und Schriftfeld verankern. Aber das geht ja selbst bei skizzierten Symbolen nicht. Auch nicht mit Verbindungspunkten.

------------------
Michael Puschner
Autodesk Inventor Certified Expert
Mensch und Maschine Scholle GmbH

Dieses Jahr mach' ich Ünflation: Jeder Beitrag, unabhängig von seinem Inhalt, bekommt von mir 10Ü, solange der Vorrat reicht.

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo

Meinst du intern besteht das Ganze nicht aus einer Tabelle? Ich denke hier flunkert uns Autodesk genauso ein Supersonderteil vor wie in ihren eigenen Symbolen. Keine Frage, sie haben eine Reihe netter Zusatzfunktionen.

Mit dem Verbindungspunkt muß ich mich korrigieren, da hast du recht. Mehr wie ein Rastpunkt beim Positionieren isses nicht. Mein Fehler 
Die beim Einrasten erzeugten GeometryIntents, an denen die eigentliche Verbindung erfolgt, sind nicht nur da so konsistent wie ein Kringel Zigarettenrauch.

------------------
MfG
Ralf

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo Canadabear,

es ist zwar nur eine "Krücke", aber Du könntest Dir eine iLogic Regel in die Zeichnungsvorlage einbauen, welche eine vorhandene Revisionstabelle immer unten links positioniert.

Bsp. iLogic Regel:

Try
Dim obj_InvDraw As inventor.drawingdocument = ThisDrawing.Document
Dim obj_BorderBox As  inventor.box2d = obj_InvDraw.ActiveSheet. Border.rangebox
Dim obj_RevBox As inventor.box2d = obj_invdraw.ActiveSheet.revisiontables.item(1).rangebox
Dim dbl_RahmenVersatz As Double = 0.5 ' Versatz um 5mm vom Rand, wg. Zonenrahmen. Wenn kein Zonenrahmen  dann 0

'Größe der Rev Tabelle berechnen
Dim int_RevTabX = obj_revbox.maxpoint.x - obj_revbox.minpoint.x
Dim int_RevTabY = obj_revbox.maxpoint.y - obj_revbox.minpoint.y

'Revisionstabelle unten links
Dim obj_InvPoint2D As  inventor.point2d = obj_invdraw.ActiveSheet.revisiontables.item(1).position
obj_Invpoint2d.y=  obj_borderbox.minpoint.y + int_RevTabY + dbl_RahmenVersatz 'Berechnung enstprechend der gewünschten Position anpassen
obj_Invpoint2d.x=obj_borderbox.minpoint.x + dbl_RahmenVersatz 'Berechnung enstprechend der gewünschten Position
obj_invdraw.ActiveSheet.revisiontables.item(1).position = obj_invpoint2d 'Rahmenposition setzen

Catch
MessageBox.Show("Revisionstabelle konnte nicht verschoben werden!", "iLogic Regel Revisionsrahmen verschieben")
Err.clear
End Try

Das Beispiel funktioniert mit nur einer Revisionstabelle auf dem aktiven Blatt!
Dies kann sicherlich noch ausgearbeitet werden...

Nachtrag:

'Positin unten rechts
obj_Invpoint2d.y=  obj_borderbox.minpoint.y + int_RevTabY + dbl_RahmenVersatz
obj_Invpoint2d.x=obj_borderbox.maxpoint.x - int_RevTabX - dbl_RahmenVersatz

Gruß

Stefan

------------------
Wer nicht mitmacht, kann auch nichts verändern

[Diese Nachricht wurde von KatzenHund am 26. Feb. 2013 editiert.]

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Guten Morgen Stefan

Genau das was ich gesucht habe Deine iLogic-Regel!
Allerdings benötige ich oben Rechts.
Könntest Du nochmals einen Nachtrag mit entsprechendem Code posten?

Besten Dank und einen schönen Tag
Gruss aus Zürich
TOM

Nachtrag dank ChatGPT:
Revisionstabelle oben rechts ohne Abstand zum Zeichnungsrahmen:

Try
    Dim obj_InvDraw As Inventor.DrawingDocument = ThisDrawing.Document
    Dim obj_BorderBox As Inventor.Box2d = obj_InvDraw.ActiveSheet.Border.RangeBox
    Dim obj_RevBox As Inventor.Box2d = obj_InvDraw.ActiveSheet.RevisionTables.Item(1).RangeBox
    Dim dbl_RahmenVersatz As Double = 0 ' Versatz um 5mm vom Rand, falls gewünscht (0 falls kein Versatz nötig)

    ' Größe der Rev-Tabelle berechnen
    Dim int_RevTabX As Double = obj_RevBox.MaxPoint.X - obj_RevBox.MinPoint.X
    Dim int_RevTabY As Double = obj_RevBox.MaxPoint.Y - obj_RevBox.MinPoint.Y

    ' Position der Revisionstabelle oben rechts berechnen
    Dim obj_InvPoint2D As Inventor.Point2d = obj_InvDraw.ActiveSheet.RevisionTables.Item(1).Position
    obj_InvPoint2D.Y = obj_BorderBox.MaxPoint.Y - dbl_RahmenVersatz ' Oben am Rand
    obj_InvPoint2D.X = obj_BorderBox.MaxPoint.X - int_RevTabX - dbl_RahmenVersatz ' Rechtsbündig

    ' Neue Position setzen
    obj_InvDraw.ActiveSheet.RevisionTables.Item(1).Position = obj_InvPoint2D

Catch
    MessageBox.Show("Revisionstabelle konnte nicht verschoben werden!", "iLogic Regel Revisionsrahmen verschieben")
    Err.Clear
End Try

[Diese Nachricht wurde von Thömse am 20. Mrz. 2025 editiert.]

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Moin

Oder man macht es gleich auswählbar.

Code:

---

Try
Dim obj_InvDraw As Inventor.DrawingDocument = ThisDrawing.Document
Dim obj_BorderBox As  Inventor.Box2d = obj_InvDraw.ActiveSheet.Border.RangeBox
Dim obj_RevBox As Inventor.Box2d = obj_InvDraw.ActiveSheet.RevisionTables.Item(1).RangeBox
Dim dbl_RahmenVersatz As Double = 0.5 ' Versatz um 5mm vom Rand, wg. Zonenrahmen. Wenn kein Zonenrahmen  dann 0

Dim oSel As String = InputListBox("Postion", New list(Of String) From {"links oben", "rechts oben", "links unten", "rechts unten"} ,"links oben" , Title := "Position Revisionstabelle", ListName := "Position")


'Größe der Rev Tabelle berechnen
Dim int_RevTabX = obj_RevBox.MaxPoint.X - obj_RevBox.MinPoint.X
Dim int_RevTabY = obj_RevBox.MaxPoint.Y - obj_RevBox.MinPoint.Y

' aktuelle Position der Revisionstabelle
Dim obj_InvPoint2D As Inventor.Point2d = obj_InvDraw.ActiveSheet.RevisionTables.Item(1).Position

Select Case oSel
Case "links oben" :
'Position oben links
obj_InvPoint2D.X = obj_BorderBox.MinPoint.X + dbl_RahmenVersatz
obj_InvPoint2D.Y = obj_BorderBox.MaxPoint.Y - dbl_RahmenVersatz
Case "rechts oben" :
'Position oben rechts
obj_InvPoint2D.X = obj_BorderBox.MaxPoint.X - int_RevTabX - dbl_RahmenVersatz
obj_InvPoint2D.Y = obj_BorderBox.MaxPoint.Y - dbl_RahmenVersatz
Case "links unten" :
'Revisionstabelle unten links
obj_InvPoint2D.X = obj_BorderBox.MinPoint.X + dbl_RahmenVersatz
obj_InvPoint2D.Y = obj_BorderBox.MinPoint.Y + int_RevTabY + dbl_RahmenVersatz
Case "rechts unten" :
'Positin unten rechts
obj_InvPoint2D.X = obj_BorderBox.MaxPoint.X - int_RevTabX - dbl_RahmenVersatz
obj_InvPoint2D.Y = obj_BorderBox.MinPoint.Y + int_RevTabY + dbl_RahmenVersatz
End Select

'Rahmenposition setzen
obj_InvDraw.ActiveSheet.RevisionTables.Item(1).Position = obj_InvPoint2D

Catch
MessageBox.Show("Revisionstabelle konnte nicht verschoben werden!", "iLogic Regel Revisionsrahmen verschieben")
Err.Clear
End Try

---

------------------
MfG
Ralf

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Guten Morgen Ralf

Das ist natürlich TOP Deine Variante.
Besten Dank

Gruss
TOM

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP